***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 09, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4410P   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 2.1		 kp = 32.5	)
.model  dds   d(
+   is = 1.621e-12	  n = 1.046		   rs = 8.284e-3
+   eg = 1.118	     trs1 = 4.588e-3 )
.model  dbody d(
+   is = 1.621e-12	  n = 1.046		   rs = 8.284e-3
+   eg = 1.118	     trs1 = 4.588e-3
+  cjo = 2.059e-10	  m = 4.111e-1		   vj = 1.473e-1
+   bv = 33		ibv = 250e-6	 
+ tbv1 = 1.215e-3      tbv2 = -2.345e-6		   tt = 25n)
.model  inter  nmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 3.688e-10	  m = 4.300e-1		   vj = 5.021e-1)
.param
+  cgs = 9.603e-10	cgd = 3.397e-10
+   rd = 2.000e-4	 ra = 2.000e-4	  
+ trd1 = 6.285e-2	trd2 = 3.085e-4
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.40 ),
+ (2.80 , 2.75 ),
+ (3.25 , 3.20 ),
+ (3.50 , 3.60 ),
+ (4.00 , 4.25 ),
+ (5.00 , 4.80 ),
+ (6.00 , 5.10 ),
+ (8.00 , 5.50 ),
+ (10.0 , 5.60 ),
+ (20.0 , 5.65 ),
+ (22.0 , 5.65 ))
egt	  1  2t   value = {4.087e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1       1t   8   6   6   inter
e1        8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd      7   4   10meg
dgd       6   4   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends 
*$
